Using Win32 functions in Visual FoxPro Image Gallery
Code examples:
GDI+: copying to the Clipboard (a) image of active FoxPro window/form, (b) image file
Adding and deleting Scheduled Tasks using NetScheduleJob API functions
How to change display settings: screen resolution, screen refresh rate
GetFileOwner - Get the owner of an NTFS file
Enumerating printer drivers installed
How to retrieve information about a cache entry (Internet Explorer)
Capturing keyboard activity of another application with the Raw Input API (VFP9)
Custom GDI+ class
GDI+: Implementing image scrolling with inertia
Mapping and disconnecting network drives
Using Video Capture: displaying on FoxPro form frames and previewing video obtained from a digital camera
Winsock: sending email messages (SMTP, port 25)
How to display Windows On-Screen Keyboard
Using WM_COPYDATA for interprocess communication (VFP9)
Converting an HTTP time/date string to a SYSTEMTIME structure
How to convert a bitmap file to monochrome format (1 bpp)
HOWTO: Use the Win32 API to Access File Dates and Times
How to display a user-defined icon in the MessageBox dialog
Transparent Menu Class (requires VFP9)
The SQLGetProp() creates a bridge between Visual FoxPro and the ODBC API
Custom HttpRequest class (WinHTTP)
Windows Shell Icons displayed and exported to ICO files (Vista)
How to detect if additional monitor is connected and active
Attaching menu to a top-level form
Obtaining names of local and global groups for current user (WinNT/XP/2K)

User rating: 10/10 (1 votes)
Rate this code sample:
  • ~
More code examples    Listed functions    Add comment     W32 Constants      Translate this page Printer friendly version of this code sample
Before you begin:
See also:
  • Enumerating global and local group accounts on a server (WinNT/XP/2K)
  • Enumerating sessions established on a server

  • DO decl
    
    cServer = ""  && empty value means local computer
    *cServer = "\\MYSERVER"
    cUser = GetUsrName()  && current user
    
    = ListGroups(cServer, cUser)  && local groups
    = ListGroups(cServer, cUser, .T.)  && global groups
    * end of main
    
    PROCEDURE ListGroups(cServer, cUser, lGlobal)
    #DEFINE MAX_PREFERRED_LENGTH -1
    
        LOCAL hBuffer, nBufsize, nReadCount, nTotalCount, nResult,;
            cBuffer, nIndex, nPtr, nOffs, nLen, cGroup
    
        STORE 0 TO nReadCount, nTotalCount, hBuffer
    
        cServer = StrConv(cServer+Chr(0), 5)
        cUser = StrConv(cUser+Chr(0), 5)
    
        IF lGlobal
            nResult = NetUserGetGroups(cServer, cUser, 0,;
                @hBuffer, MAX_PREFERRED_LENGTH, @nReadCount, @nTotalCount)
        ELSE
            nResult = NetUserGetLocalGroups(cServer, cUser, 0,0,;
                @hBuffer, MAX_PREFERRED_LENGTH, @nReadCount, @nTotalCount)
        ENDIF
    
        IF nResult <> 0 Or hBuffer=0
            = NetApiBufferFree(hBuffer)
            ? "Error code:", nResult
            RETURN
        ENDIF
    
        * size of the buffer allocated by the system
        * GlobalSize on Windows XP returns same result
        nBufsize = 0
        = NetApiBufferSize(hBuffer, @nBufsize)
    
        * copying data from memory buffer to FoxPro string
        cBuffer = Repli(Chr(0), nBufsize)
        CopyMemory(@cBuffer, hBuffer, nBufsize)
    
        * scanning group names
        FOR nIndex=1 TO nTotalCount
            * retrieving 4-byte (DWORD) address of Unicode string
            * that specifies the group name
            nPtr = buf2dword(SUBSTR(cBuffer, (nIndex-1)*4+1,4))
    
            * matching memory addresses to cBuffer string
            nOffs = nPtr - hBuffer + 1
            cGroup = SUBSTR(cBuffer, nOffs)+Chr(0)+Chr(0)
            nLen = AT(Chr(0)+Chr(0), cGroup)
            cGroup = SUBSTR(cGroup, 1, nLen)
    
            ? nIndex, StrConv(cGroup, 6)
        ENDFOR
        = NetApiBufferFree(hBuffer)
    
    FUNCTION GetUsrName
    * actually SYS(0) is Ok too :)
        LOCAL cBuffer, nBufsize
        nBufsize = 32
        cBuffer = Repli(Chr(0), nBufsize)
        = GetUserName(@cBuffer, @nBufsize)
    RETURN STRTRAN(cBuffer, Chr(0), "")
    
    PROCEDURE decl
        DECLARE INTEGER NetUserGetGroups IN netapi32;
            STRING servername, STRING username, INTEGER lvl,;
            INTEGER @bufptr, INTEGER prefmaxlen,;
            INTEGER @entriesread, INTEGER @totalentries
    
        DECLARE INTEGER NetUserGetLocalGroups IN netapi32;
            STRING servername, STRING username, INTEGER lvl,;
            INTEGER flgs, INTEGER @bufptr, INTEGER prefmaxlen,;
            INTEGER @entriesread, INTEGER @totalentries
    
        DECLARE INTEGER GetUserName IN advapi32;
            STRING  @lpBuffer, INTEGER @nSize
    
        DECLARE RtlMoveMemory IN kernel32 As CopyMemory;
            STRING @dst, INTEGER src, INTEGER bufsize
    
        DECLARE INTEGER NetApiBufferFree IN netapi32 INTEGER buffer
    
        DECLARE INTEGER NetApiBufferSize IN netapi32;
            INTEGER Buffer, INTEGER @ByteCount
    
    FUNCTION buf2dword(lcBuffer)
    RETURN Asc(SUBSTR(lcBuffer, 1,1)) + ;
        BitLShift(Asc(SUBSTR(lcBuffer, 2,1)),  8) +;
        BitLShift(Asc(SUBSTR(lcBuffer, 3,1)), 16) +;
        BitLShift(Asc(SUBSTR(lcBuffer, 4,1)), 24)
    
    
    

    User rating: 10/10 (1 votes)
    Rate this code sample:
    • ~
    2866 bytes  
    Created: 2003-12-05 20:41:44  
    Modified: 2011-12-10 09:20:22  
    Visits in 7 days: 31  
    Listed functions:
    GetUserName
    GlobalSize
    NetApiBufferFree
    NetApiBufferSize
    NetUserGetGroups
    NetUserGetLocalGroups
    Printer friendly API declarations
    Word Index links for this example:
    Translate this page:
      Spanish    Portuguese    German    French    Italian  
    FreeTranslation.com offers instant, free translations of text or web pages.
    User Contributed Notes:
    There are no notes on this subject.


    Copyright 2001-2014 News2News, Inc. Before reproducing or distributing any data from this site please ask for an approval from its owner. Unless otherwise specified, this page is for your personal and non-commercial use. The information on this page is presented AS IS, meaning that you may use it at your own risk. Microsoft Visual FoxPro and Windows are trade marks of Microsoft Corp. All other trademarks are the property of their respective owners. 

    Privacy policy
    Credits: PHP (4.4.9), an HTML-embedded scripting language, MySQL (5.1.68), the Open Source standard SQL database, AceHTML Freeware Version 4, freeware HTML Editor of choice.   Hosted by Korax Online Inc.
    Last Topics Visited (54.197.45.100)
    1.07 min.Function: 'SQLTables'
    2.57 min.Function: 'CreateWindowEx'
    6.08 min.Function: 'midiOutGetNumDevs'
    Function group: 'Windows Multimedia'
    8.63 hrs.Example: 'Retrieving the state of your Internet connection'
    8.64 hrs.Function: 'GetWindowLong'
    8.66 hrs.Function: 'CryptHashData'
    Function group: 'Cryptography Reference'
    2 day(s)Function: 'HeapSize'
     
    Function group: 'Authentication'
     Function: 'FillRect'
     Example: 'Retrieving information specific to the current Time Zone'
    Google
    Advertise here!