Using Win32 functions in Visual FoxPro Image Gallery
Network Management
..msdn
NetApiBufferFree
NetApiBufferSize
NetConnectionEnum
NetFileClose
NetFileEnum
NetFileGetInfo
NetGetDCName
NetGroupEnum
NetLocalGroupEnum
NetMessageBufferSend
NetMessageNameAdd
NetMessageNameDel
NetMessageNameEnum
NetScheduleJobAdd
NetScheduleJobDel
NetScheduleJobEnum
NetServerEnum
NetServerGetInfo
NetSessionEnum
NetShareAdd
NetShareDel
NetShareEnum
NetShareSetInfo
NetUserAdd
NetUserChangePassword
NetUserDel
NetUserEnum
NetUserGetGroups
NetUserGetInfo
NetUserGetLocalGroups
NetUserSetInfo
NetWkstaGetInfo
NetWkstaTransportEnum
NetWkstaUserEnum
Code examples:
Adding and deleting Scheduled Tasks using NetScheduleJob API functions
Adding and deleting User Accounts
Enumerating connections made to a shared resource for the local computer (WinNT only)
Enumerating files opened on the network
Enumerating global and local group accounts on a server (WinNT/XP/2K)
Enumerating network sessions established on a server
Enumerating servers of the specified type (e.g. SQL Server) in the primary domain
Finding out if the current user is the Guest account
How to enumerate, add and delete shares on the local computer (WinNT/XP)
Obtaining information about all user accounts on a server (WinNT only)
Obtaining names of local and global groups for current user (WinNT/XP/2K)
Retrieving configuration information for the specified server (Win2000/XP)
Retrieving configuration information for the specified workstation (Win2000/XP)
Retrieving information about all users currently logged on to the workstation (WinNT only)
Retrieving the name of the primary domain controller (PDC) and join status information
Using NetWkstaTransportEnum to obtain MAC Address of remote server
Using the NetMessageBufferSend to send messages on the network
Obtaining names of local and global groups for current user (WinNT/XP/2K)

User rating: 10/10 (1 votes)
Rate this code sample:
  • ~
More code examples    Listed functions    Add comment     W32 Constants      Translate this page Printer friendly version of this code sample
Before you begin:
See also:
  • Enumerating global and local group accounts on a server (WinNT/XP/2K)
  • Enumerating sessions established on a server

  • DO decl
    
    cServer = ""  && empty value means local computer
    *cServer = "\\MYSERVER"
    cUser = GetUsrName()  && current user
    
    = ListGroups(cServer, cUser)  && local groups
    = ListGroups(cServer, cUser, .T.)  && global groups
    * end of main
    
    PROCEDURE ListGroups(cServer, cUser, lGlobal)
    #DEFINE MAX_PREFERRED_LENGTH -1
    
        LOCAL hBuffer, nBufsize, nReadCount, nTotalCount, nResult,;
            cBuffer, nIndex, nPtr, nOffs, nLen, cGroup
    
        STORE 0 TO nReadCount, nTotalCount, hBuffer
    
        cServer = StrConv(cServer+Chr(0), 5)
        cUser = StrConv(cUser+Chr(0), 5)
    
        IF lGlobal
            nResult = NetUserGetGroups(cServer, cUser, 0,;
                @hBuffer, MAX_PREFERRED_LENGTH, @nReadCount, @nTotalCount)
        ELSE
            nResult = NetUserGetLocalGroups(cServer, cUser, 0,0,;
                @hBuffer, MAX_PREFERRED_LENGTH, @nReadCount, @nTotalCount)
        ENDIF
    
        IF nResult <> 0 Or hBuffer=0
            = NetApiBufferFree(hBuffer)
            ? "Error code:", nResult
            RETURN
        ENDIF
    
        * size of the buffer allocated by the system
        * GlobalSize on Windows XP returns same result
        nBufsize = 0
        = NetApiBufferSize(hBuffer, @nBufsize)
    
        * copying data from memory buffer to FoxPro string
        cBuffer = Repli(Chr(0), nBufsize)
        CopyMemory(@cBuffer, hBuffer, nBufsize)
    
        * scanning group names
        FOR nIndex=1 TO nTotalCount
            * retrieving 4-byte (DWORD) address of Unicode string
            * that specifies the group name
            nPtr = buf2dword(SUBSTR(cBuffer, (nIndex-1)*4+1,4))
    
            * matching memory addresses to cBuffer string
            nOffs = nPtr - hBuffer + 1
            cGroup = SUBSTR(cBuffer, nOffs)+Chr(0)+Chr(0)
            nLen = AT(Chr(0)+Chr(0), cGroup)
            cGroup = SUBSTR(cGroup, 1, nLen)
    
            ? nIndex, StrConv(cGroup, 6)
        ENDFOR
        = NetApiBufferFree(hBuffer)
    
    FUNCTION GetUsrName
    * actually SYS(0) is Ok too :)
        LOCAL cBuffer, nBufsize
        nBufsize = 32
        cBuffer = Repli(Chr(0), nBufsize)
        = GetUserName(@cBuffer, @nBufsize)
    RETURN STRTRAN(cBuffer, Chr(0), "")
    
    PROCEDURE decl
        DECLARE INTEGER NetUserGetGroups IN netapi32;
            STRING servername, STRING username, INTEGER lvl,;
            INTEGER @bufptr, INTEGER prefmaxlen,;
            INTEGER @entriesread, INTEGER @totalentries
    
        DECLARE INTEGER NetUserGetLocalGroups IN netapi32;
            STRING servername, STRING username, INTEGER lvl,;
            INTEGER flgs, INTEGER @bufptr, INTEGER prefmaxlen,;
            INTEGER @entriesread, INTEGER @totalentries
    
        DECLARE INTEGER GetUserName IN advapi32;
            STRING  @lpBuffer, INTEGER @nSize
    
        DECLARE RtlMoveMemory IN kernel32 As CopyMemory;
            STRING @dst, INTEGER src, INTEGER bufsize
    
        DECLARE INTEGER NetApiBufferFree IN netapi32 INTEGER buffer
    
        DECLARE INTEGER NetApiBufferSize IN netapi32;
            INTEGER Buffer, INTEGER @ByteCount
    
    FUNCTION buf2dword(lcBuffer)
    RETURN Asc(SUBSTR(lcBuffer, 1,1)) + ;
        BitLShift(Asc(SUBSTR(lcBuffer, 2,1)),  8) +;
        BitLShift(Asc(SUBSTR(lcBuffer, 3,1)), 16) +;
        BitLShift(Asc(SUBSTR(lcBuffer, 4,1)), 24)
    
    
    

    User rating: 10/10 (1 votes)
    Rate this code sample:
    • ~
    2866 bytes  
    Created: 2003-12-05 20:41:44  
    Modified: 2011-12-10 09:20:22  
    Visits in 7 days: 164  
    Listed functions:
    GetUserName
    GlobalSize
    NetApiBufferFree
    NetApiBufferSize
    NetUserGetGroups
    NetUserGetLocalGroups
    Printer friendly API declarations
    Word Index links for this example:
    Translate this page:
      Spanish    Portuguese    German    French    Italian  
    FreeTranslation.com offers instant, free translations of text or web pages.
    User Contributed Notes:
    There are no notes on this subject.


    Copyright 2001-2017 News2News, Inc. Before reproducing or distributing any data from this site please ask for an approval from its owner. Unless otherwise specified, this page is for your personal and non-commercial use. The information on this page is presented AS IS, meaning that you may use it at your own risk. Microsoft Visual FoxPro and Windows are trade marks of Microsoft Corp. All other trademarks are the property of their respective owners. 

    Privacy policy
    Credits: PHP (4.4.9), an HTML-embedded scripting language, MySQL (5.6.38), the Open Source standard SQL database, AceHTML Freeware Version 4, freeware HTML Editor of choice.   Hosted by Korax Online Inc.
    Last Topics Visited (54.227.127.109)
    15 sec.Function: 'midiOutReset'
    Function group: 'Windows Multimedia'
    29 sec.Function: 'CeRapiInit'
    Function group: 'Remote Application Programming (RAPI)'
    42 sec.Function: 'waveOutGetVolume'
    Function group: 'Windows Multimedia'
    55 sec.Example: 'How to play AVI file on the _screen'
    1.1 min.Example: 'Copying picture of the active form to the Clipboard using Enhanced Metafile API functions'
    1.4 min.Function: 'timeGetDevCaps'
    Function group: 'Windows Multimedia'
    1.63 min.Function: 'CeRapiInitEx'
    Function group: 'Remote Application Programming (RAPI)'
    1.88 min.Function: 'NetUserGetInfo'
    Function group: 'Network Management'
    2.15 min.Function: 'waveOutUnprepareHeader'
    Function group: 'Windows Multimedia'
    2.4 min.Function: 'CeMoveFile'
    Function group: 'Remote Application Programming (RAPI)'
    Google
    Advertise here!