SET PROCEDURE TO clsRapi ADDITIVE
SET PROCEDURE TO clsRapiDb ADDITIVE
 
LOCAL oRapi As TrapiDb
oRapi = CREATEOBJECT("TrapiDb")
 
IF NOT oRapi.Connected
    = MESSAGEBOX("Mobile device is unavailable.     ", 48, "Error")
    RETURN
ENDIF
 
LOCAL db, nIndex, firstname, middlename, lastname, email,;
    cellphone, homephone, note23, ex As Exception
 
TRY
    db = oRapi.databases.GetDatabase("Contacts Database")
*    db = oRapi.databases.GetDatabase("dbContactsCopy")
 
    IF db.OpenDatabase()
        CREATE CURSOR contacts (firstname C(15), middlename C(15),;
            lastname C(25), cellphone C(20), homephone C(20),;
            email C(50), note23 M)
 
        FOR nIndex=0 TO db.dbreccount-1
            db.goto(nIndex)
 
            firstname = FromUnicode(db.props.GetValue("14854", ""))
            middlename = FromUnicode(db.props.GetValue("16420", ""))
            lastname = FromUnicode(db.props.GetValue("14865", ""))
            email = FromUnicode(db.props.GetValue("16515", ""))
            cellphone = FromUnicode(db.props.GetValue("14876", ""))
            homephone = FromUnicode(db.props.GetValue("14857", ""))
            note23 = db.props.GetValue("23", "")
 
            INSERT INTO contacts VALUES (;
                m.firstname, m.middlename, m.lastname,;
                m.cellphone, m.homephone, m.email, m.note23)
        ENDFOR
        db.CloseDatabase
    ELSE
        = MESSAGEBOX("Could not open requested database.     ",;
            48, "Error")
    ENDIF
 
CATCH TO ex
    = MESSAGEBOX("Error: " + TRANSFORM(ex.ErrorNo) + ". " +;
        ex.Message + ".     ", 48, "Error")
ENDTRY
 
IF USED("contacts")
    SELECT contacts
    GO TOP
    BROWSE NORMAL NOWAIT
ENDIF