Using Win32 functions in Visual FoxPro Image Gallery
Code examples:
Yet another modal dialog: now HTML-based
GDI+: loading image file, drawing on it, saving the result to another file
Quering Audio Mixer Device
How to download a file from HTTP server using URL Monikers functions
Reading the structure of VFP main menu
Using the NetMessageBufferSend to send messages on the network
Confining Windows calculator inside the VFP main window
Converting command-line string to a set of Unicode argument strings
How to adjust monitor brightness (Vista, monitor with DDC support)
How to Start a Process as Another User (NT/XP/2K)
OS version and revision
How to build UDP responder
HOWTO: Use the Win32 API to Access File Dates and Times
Using NetWkstaTransportEnum to obtain MAC Address of remote server
Creating a directory on the FTP
Enumerating ports that are available for printing on a specified server
Creating the Save dialog box to specify the drive, directory, and name of a file to save
Custom HttpRequest class (WinINet)
GDI+: Color Transparency
How to create transparent areas inside a form -- punching holes in the form
How to read email messages using Simple MAPI
PocketPC: custom RAPI class for executing routines on remote Windows CE device
Extensible Storage Engine class library
How to browse and connect to printers on a network (WinNT)
How to enumerate terminal servers within the specified Windows domain

User rating: 0/10 (0 votes)
Rate this code sample:
  • ~
More code examples    Listed functions    Add comment     W32 Constants      Translate this page Printer friendly version of this code sample
Before you begin:
See also:
  • How to enumerate sessions and processes on a specified terminal server

  • DO declare
    
    LOCAL cDomainName, hBuffer, nSvrIndex, nSvrCount, nBufsize,;
        cBuffer, nAddress, cSvrName
    
    STORE 0 TO hBuffer, nSvrCount
    
    * The first parameter is the name of Windows domain to be queried.
    * If this parameter is NULL, the current domain is assumed.
    cDomainName=NULL
    *cDomainName="companydomain"
    
    nResult = WTSEnumerateServers(cDomainName, 0, 1, @hBuffer, @nSvrCount)
    
    IF nResult = 0
    * 1212=invalid domain name/format
        ? "WTSEnumerateServers failed with error:", GetLastError()
        RETURN
    ENDIF
    
    ? "Number of terminal servers within the domain:", nSvrCount
    
    * create VFP string variable and allocate amount of space
    * required to store the array of WTS_SERVER_INFO structures
    * created by WTSEnumerateServers function
    nBufsize = GlobalSize(hBuffer)
    cBuffer = REPLICATE(CHR(0), nBufsize)
    = MemToStr(@cBuffer, hBuffer, nBufsize)
    
    *    The array of WTS_SERVER_INFO structures starts with 
    * N DWORD (4-byte) values, where N is the number 
    * of terminal servers detected.
    *    Each value is the address in memory where a terminal server
    * name is stored.
    *    Each terminal server name ends with zero byte.
    
    * retrieve terminal server names from the array
    FOR nSvrIndex=0 TO nSvrCount-1
        nAddress = buf2dword(SUBSTR(cBuffer, nSvrIndex*4+1, 4))
        cSvrName = SUBSTR(cBuffer, nAddress - hBuffer+1)
        cSvrName = SUBSTR(m.cSvrName, 1, AT(CHR(0),cSvrName)-1)
        ? "["+cSvrName+"]"
    NEXT
    
    * release memory implicitly allocated by the WTSEnumerateServers
    = WTSFreeMemory(hBuffer)
    * end of main
    
    PROCEDURE declare
        DECLARE INTEGER GetLastError IN kernel32
        DECLARE WTSFreeMemory IN Wtsapi32 INTEGER pMemory
        DECLARE INTEGER GlobalSize IN kernel32 INTEGER hMem
    
        DECLARE INTEGER WTSEnumerateServers IN Wtsapi32;
            STRING pDomainName, LONG Reserved, LONG RqVersion,;
            LONG @ppServerInfo, LONG @SICount
    
        DECLARE RtlMoveMemory IN kernel32 As MemToStr; 
            STRING @dst, INTEGER src, INTEGER ByteCount
    
    FUNCTION buf2dword(lcBuffer)
    RETURN Asc(SUBSTR(lcBuffer, 1,1)) + ;
        BitLShift(Asc(SUBSTR(lcBuffer, 2,1)),  8) +;
        BitLShift(Asc(SUBSTR(lcBuffer, 3,1)), 16) +;
        BitLShift(Asc(SUBSTR(lcBuffer, 4,1)), 24)
    
    
    

    User rating: 0/10 (0 votes)
    Rate this code sample:
    • ~
    2157 bytes  
    Created: 2006-12-29 16:20:17  
    Modified: 2006-12-29 16:33:08  
    Visits in 7 days: 126  
    Listed functions:
    GetLastError
    GlobalSize
    WTSEnumerateServers
    WTSFreeMemory
    Printer friendly API declarations
    Word Index links for this example:
    Translate this page:
      Spanish    Portuguese    German    French    Italian  
    FreeTranslation.com offers instant, free translations of text or web pages.
    User Contributed Notes:
    There are no notes on this subject.


    Copyright 2001-2017 News2News, Inc. Before reproducing or distributing any data from this site please ask for an approval from its owner. Unless otherwise specified, this page is for your personal and non-commercial use. The information on this page is presented AS IS, meaning that you may use it at your own risk. Microsoft Visual FoxPro and Windows are trade marks of Microsoft Corp. All other trademarks are the property of their respective owners. 

    Privacy policy
    Credits: PHP (4.4.9), an HTML-embedded scripting language, MySQL (5.6.38), the Open Source standard SQL database, AceHTML Freeware Version 4, freeware HTML Editor of choice.   Hosted by Korax Online Inc.
    Last Topics Visited (23.22.136.56)
    22 sec.Solution: 'Extended MessageBox Library (assembly) for .NET'
    43 sec.Function: 'DrawMenuBar'
    1.08 min.Function: 'WindowProc'
    1.48 min.
    Function group: 'Device Input and Output'
    1.88 min.Function: 'WriteFile'
    2.27 min.Function: 'mixerClose'
    2.62 min.Function: 'InternetCanonicalizeUrl'
    3.03 min.Function: 'CryptGetProvParam'
    Function group: 'Cryptography Reference'
    3.43 min.Function: 'StartPage'
    Function group: 'Printing and Print Spooler'
    3.87 min.Function: 'GetTextColor'
    Google
    Advertise here!